DIM title$(100)
scrh = 190
scrw = 640
bord = scrw * .03
squarw = .08 * scrw
squarh = .45 * scrh
interw = .015 * scrw
SCREEN 2

'Load the full playlist file names:

OPEN "c:\playlist.txt" FOR INPUT AS #1
LINE INPUT #1, nbtitr$
nb = VAL(nbtitr$)
FOR i = 1 TO nb
        LINE INPUT #1, title$(i)
NEXT i
CLOSE #1

'Playing the files by calling mpxplay:

i = 1
WHILE i <= nb
       
               'Display track number on video driven LED unit
                GOSUB disptrack

                'Launch mpxplay in video quiet mode
                SHELL "mpxplay.exe -cm -sl0 -ddma -f0 -v -bl -bn8 " + title$(i)

                'mpxplay has completed or been interrupted
                SLEEP 1
                com$ = INKEY$

                'Case of a "stop all":
                IF com$ = "E" OR com$ = "e" THEN
                        i = nb
                END IF

                'Case of a "skip back":
                IF com$ = "B" OR com$ = "b" THEN
                        IF i >= 2 THEN
                                i = i - 2
                        END IF
                END IF
                        
                'In case of normal end or skip FWD, step to following title
                i = i + 1
WEND
CLS
' Exit while setting green led on as "ready" status:
lft = bord + (interw + squarw) * 7
LINE (lft, 0)-(lft + squarw, squarh), 1, BF

END

'Display the "i" value with two 10-LED lines (unity and tenthes)
disptrack:
        CLS
        diz = INT(i / 10)
        IF diz <> 0 THEN
                'Tenth display
                IF diz >= 3 THEN
                        ddiz = diz - 2
                ELSE
                        ddiz = diz + 8
                END IF
                lft = (interw + squarw) * (ddiz - 1) + bord
                LINE (lft, 0)-(lft + squarw, squarh), 1, BF
        END IF
        unit = i - diz * 10
        'Unity display:
        IF unit >= 2 THEN
                dunit = unit - 2
        ELSE
                dunit = unit + 8
        END IF
        lft = (interw + squarw) * dunit + bord
        LINE (lft, scrh - squarh)-(lft + squarw, scrh), 1, BF
RETURN